Thank you!
I looked into the independent randomization and I´m afraid the experiment Im trying to replicate is different, because Im not using the trial-type negative-misophonic.
I do have the Inquisit code, but sadly I can`t figure out a way to replicate this using PsychoPy.
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
/ posttrialpause = 500
</defaults>
************************** stimuli *****************************
<text negativeright>
/ items = negative
/ select = noreplace
/ position = (70, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<text negativeleft>
/ items = negative
/ select = noreplace
/ position = (30, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<item negative>
/1="berauben"
/2="betrügen"
/3="drohen"
/4="fürchten"
/5="gefährden"
/6="klauen"
/7="schießen"
/8="schlagen"
/9="stehlen"
/10="verletzen"
/11="zerstören"
/12="zwingen"
</item>
<text neutralright>
/ items = neutral
/ select = noreplacenot (neutralleft)
/ position = (70, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<text neutralleft>
/ items = neutral
/ select = noreplacenot (neutralright)
/ position = (30, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<text neutralnegright>
/ items = neutralneg
/ select = noreplace
/ position = (70, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<text neutralnegleft>
/ items = neutralneg
/ select = noreplace
/ position = (30, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<item neutral>
/1="ahnen"
/2="anlegen"
/3="auftreten"
/4="bedienen"
/5="betragen"
/6="beweisen"
/7="binden"
/8="bitten"
/9="drücken"
/10="einsetzen"
/11="eintreten"
/12="erfassen"
</item>
<item neutralneg>
/1="erheben"
/2="erteilen"
/3="gehören"
/4="gelten"
/5="greifen"
/6="heben"
/7="neigen"
/8="nennen"
/9="stapeln"
/10="tragen"
/11="vermuten"
/12="weisen"
</item>
<text misophoniaright>
/ items = misophonia
/ select = noreplace
/ position = (70, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<text misophonialeft>
/ items = misophonia
/ select = noreplace
/ position = (30, 50)
/ txcolor = (0, 0, 0)
/ fontstyle = ("Arial", 4%, false, false, false, false, 5, 0)
</text>
<item misophonia>
/1="abbeißen"
/2="essen"
/3="kauen"
/4="knabbern"
/5="knirschen"
/6="knistern"
/7="schlucken"
/8="schlürfen"
/9="schmatzen"
/10="schnauben"
/11="schnaufen"
/12="trinken"
</item>
<shape probeleft>
/ shape = circle
/ size = (1%, 1%)
/ color = (200, 200, 200)
/ position = (30%, 50%)
</shape>
<shape proberight>
/ shape = circle
/ size = (1%, 1%)
/ color = (200, 200, 200)
/ position = (70%, 50%)
</shape>
<text fixation>
/ items = ("+")
</text>
<text erasefixation>
/ items = ("+")
/ txcolor = (255, 255, 255)
</text>
<shape erasewords>
/ color = (255, 255, 255)
/ size = (90%, 90%)
</shape>
*************************** Instructions *******************
<instruct>
/ nextlabel = "Drücken Sie bitte die Leertaste um weiterzukommen"
/ lastlabel = "Drücken Sie bitte die Leertaste um weiterzukommen"
/ nextkey = (" ")
/ fontstyle = ("Arial", 2%, false, false, false, false, 5, 0)
</instruct>
<page begin>
^^Im Folgenden werden wir Ihre Reaktionszeit testen. Bei jedem Durchgang wird ein Fixierkreuz (+) für 500 ms präsentiert.
^^Bitte schauen Sie auf das Kreuz, wenn es präsentiert wird. Danach erscheinen links und rechts vom Kreuz zwei Wörter für jeweils 500 ms.
^^Beide Wörter werden dann vom Bildschirm gelöscht und an Stelle eines der beiden Wörter erscheint ein grauer Punkt.
^^Ihre Aufgabe ist es, so schnell wie möglich auf diesen Punkt zu reagieren:
^^Wenn der Punkt auf der linken Seite erscheint, drücken Sie bitte den Buchstaben "E".
^^Wenn der Punkt auf der rechten Seite erscheint, drücken Sie bitte den Buchstaben "I".
^^Arbeiten Sie so schnell und genau wie möglich.
</page>
<page practice>
^^Sie haben jetzt Gelegenheit, das Vorgehen kurz zu üben. Bitte platzieren Sie den linken Zeigefinger auf dem Buchstaben E und den rechten Zeigefinger auf dem Buchstaben I.
^^Zur Erinnerung:
^^Wenn der Punkt auf der linken Seite erscheint, drücken Sie bitte den Buchstaben "E".
^^Wenn der Punkt auf der rechten Seite erscheint, drücken Sie bitte den Buchstaben "I".
</page>
<page test>
^^Es beginnt jetzt die eigentliche Untersuchung. Bitte platzieren Sie den linken Zeigefinger auf dem Buchstaben E und den rechten Zeigefinger auf dem Buchstaben I.
^^Zur Erinnerung:
^^Wenn der Punkt auf der linken Seite erscheint, drücken Sie bitte den Buchstaben "E".
^^Wenn der Punkt auf der rechten Seite erscheint, drücken Sie bitte den Buchstaben "I".
</page>
<page Pause>
^^Bevor die Untersuchung weitergeht, haben Sie nun die Möglichkeit, sich kurz auszuruhen.
^^Sobald Sie sich erholt haben, können Sie die Untersuchung fortführen.
</page>
<page test2>
^^Es beginnt jetzt der zweite Teil der Untersuchung. Bitte platzieren Sie den linken Zeigefinger auf dem Buchstaben E und den rechten Zeigefinger auf dem Buchstaben I.
^^Zur Erinnerung:
^^Wenn der Punkt auf der linken Seite erscheint, drücken Sie bitte den Buchstaben "E".
^^Wenn der Punkt auf der rechten Seite erscheint, drücken Sie bitte den Buchstaben "I".
</page>
<page end>
^^^Herzlichen Dank für Ihre Mitarbeit
</page>
*************************** trials **********************
<trial negneuleft>
/ correctresponse = ("e")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, negativeleft, neutralnegright; 1000=erasewords, probeleft]
</trial>
<trial negneuright>
/ correctresponse = ("i")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, negativeleft, neutralnegright; 1000=erasewords, proberight]
</trial>
<trial neunegleft>
/ correctresponse = ("e")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralnegleft, negativeright; 1000=erasewords, probeleft]
</trial>
<trial neunegright>
/ correctresponse = ("i")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralnegleft, negativeright; 1000=erasewords, proberight]
</trial>
<trial misoneuleft>
/ correctresponse = ("e")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, misophonialeft, neutralnegright; 1000=erasewords, probeleft]
</trial>
<trial misoneuright>
/ correctresponse = ("i")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, misophonialeft, neutralnegright; 1000=erasewords, proberight]
</trial>
<trial neumisoleft>
/ correctresponse = ("e")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralnegleft, misophoniaright; 1000=erasewords, probeleft]
</trial>
<trial neumisoright>
/ correctresponse = ("i")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralnegleft, misophoniaright; 1000=erasewords, proberight]
</trial>
<trial neuneuleft>
/ correctresponse = ("e")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralleft, neutralright; 1000=erasewords, probeleft]
</trial>
<trial neuneuright>
/ correctresponse = ("i")
/ validresponse = ("e", "i")
/ stimulustimes = [0=fixation; 500=erasefixation, neutralleft, neutralright; 1000=erasewords, proberight]
</trial>
********************** blocks ***************************
<block practice>
/ preinstructions = (practice)
/ trials = [1-6=noreplace(neuneuleft, neuneuright)]
</block>
<block test>
/ preinstructions = (test)
/ trials = [1-144=noreplace(negneuleft, negneuright, neunegleft, neunegright, misoneuleft, misoneuright, neumisoleft, neumisoright, neuneuleft, neuneuright, neuneuleft, neuneuright)]
/ postinstructions = (Pause)
</block>
<block test2>
/ preinstructions = (test2)
/ trials = [1-144=noreplace(negneuleft, negneuright, neunegleft, neunegright, misoneuleft, misoneuright, neumisoleft, neumisoright, neuneuleft, neuneuright, neuneuleft, neuneuright)]
</block>
************************** experiment************************
<expt>
/ preinstructions = (begin)
/ blocks = [1=practice; 2=test; 3=test2]
/ postinstructions = (end)
</expt>
Is there maybe another way to replicate this experiment?
Or is it infact possible by using (a maybe altered) independent randomization?
I programmed my experiment by using the Builder and sadly I cannot translate this code into JavaScript or Python, for it to work in PsychoPy.
Thank you very much for your help! Sadly I`m very new to PsychoPy so I´m having difficulties solving problems like these by myself.
